MINI MINI MANI MO

<?xml version="1.0"?>
<!-- 
NAME
    kuconsum.xsl
DESCRIPTION
    XSLT stylesheet for XML => DDL conversion of ku$_rmgr_consumer_t ADTs
NOTES
    Do NOT modify this file under any circumstance. Copy the file
    if you wish to use this stylesheet with an external XML/XSL parser

MODIFIED        MM/DD/YY
    sdavidso    02/14/17 - bug25440009 handle user name with apostrophe
    bwright     08/15/13 - Bug 17312600: Remove hard tabs from DP src code
    lbarton     11/02/05 - Bug 4715313: reformat files for use with XMLSpy 
    htseng      08/02/02 - add grantee parse param
    htseng      07/26/02 - add more parse params
    htseng      04/03/02 - htseng_rmgr_obj_support
    htseng      11/15/01 - Creation 
 -->
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <!-- Import required scripts -->
 <xsl:import href="kucommon.xsl"/>
 <!-- Top-level parameters -->
 <xsl:param name="PRETTY">1</xsl:param>
 <xsl:param name="SQLTERMINATOR">1</xsl:param>
 <xsl:param name="EXPORT">1</xsl:param>
 <!-- params for parse -->
 <xsl:param name="PRS_DDL">0</xsl:param>
 <xsl:param name="PRS_DELIM">\{]`</xsl:param>
 <xsl:param name="PRS_VERB">0</xsl:param>
 <xsl:param name="PRS_OBJECT_TYPE">0</xsl:param>
 <xsl:param name="PRS_SCHEMA">0</xsl:param>
 <xsl:param name="PRS_NAME">0</xsl:param>
 <xsl:param name="PRS_GRANTEE">0</xsl:param>
 <xsl:param name="PRS_GRANTOR">0</xsl:param>
 <xsl:param name="PRS_BASE_OBJECT_TYPE">0</xsl:param>
 <xsl:param name="PRS_BASE_OBJECT_SCHEMA">0</xsl:param>
 <xsl:param name="PRS_BASE_OBJECT_NAME">0</xsl:param>
 <xsl:template match="RMGR_CONSUMER_T">
  <xsl:call-template name="DoParse">
   <xsl:with-param name="Verb">DBMS_RESOURCE_MANAGER.CREATE_CONSUMER_GROUP</xsl:with-param>
   <xsl:with-param name="ObjectType">RMGR_CONSUMER_GROUP</xsl:with-param>
   <xsl:with-param name="SchemaNode" select="SCHEMA_OBJ/OWNER_NAME"/>
   <xsl:with-param name="NameNode" select="SCHEMA_OBJ/NAME"/>
  </xsl:call-template>
  <xsl:text> BEGIN </xsl:text>
  <xsl:if test="$PRETTY=1">
   <xsl:text>&#xa;</xsl:text>
  </xsl:if>
  <xsl:text>   DBMS_RESOURCE_MANAGER.CREATE_CONSUMER_GROUP(</xsl:text>
  <xsl:if test="$PRETTY=1">
   <xsl:text>&#xa;</xsl:text>
  </xsl:if>
  <xsl:text>     consumer_group      => '</xsl:text>
  <xsl:call-template name="EnQuote">
   <xsl:with-param name="String" select="SCHEMA_OBJ/NAME"/>
  </xsl:call-template>
  <xsl:text>',</xsl:text>
  <xsl:if test="$PRETTY=1">
   <xsl:text>&#xa;</xsl:text>
  </xsl:if>
  <xsl:if test="string-length(DESCRIPTION)!=0">
   <xsl:text>     comment   => '</xsl:text>
   <xsl:call-template name="EnQuote">
    <xsl:with-param name="String" select="DESCRIPTION"/>
   </xsl:call-template>
   <xsl:text>',</xsl:text>
   <xsl:if test="$PRETTY=1">
    <xsl:text>&#xa;</xsl:text>
   </xsl:if>
  </xsl:if>
  <xsl:text>     cpu_mth   => '</xsl:text>
  <xsl:call-template name="EnQuote">
   <xsl:with-param name="String" select="CPU_METHOD"/>
  </xsl:call-template>
  <xsl:text>')</xsl:text>
  <xsl:if test="$SQLTERMINATOR=1">
   <xsl:text>;</xsl:text>
  </xsl:if>
  <xsl:if test="$PRETTY=1">
   <xsl:text>&#xa;</xsl:text>
  </xsl:if>
  <xsl:text> END</xsl:text>
  <xsl:if test="$SQLTERMINATOR=1">
   <xsl:text>;</xsl:text>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>